There is only one instance where MarsEdit’s windowy layout truly frustrates me. When I click on MarsEdit’s dock icon, the great majority of the time it’s because I have a flash idea and want to write a post. Instead of a fresh document window, however, I’m greeted with the blog manager window.

Easily managing multiple blogs, saving local drafts and editing already published posts are surely some of the features that make MarsEdit a joy to use, but for me the application is about writing. When I hit the dock icon I want to be articulating my thoughts within seconds. The blog manager, for all its usefulness, pretty much just gets in the way.

Here’s an AppleScript that will open up a new document window and bypass the blog manager altogether:

if appIsRunning("MarsEdit") then
	tell application "MarsEdit"
		set docCount to (count every document)
		if docCount is equal to 0 then
			launch
			close window "MarsEdit"
			make new document
			activate
		else
			tell document 1 to activate
		end if
	end tell
else
	tell application "MarsEdit"
		run
		close window "MarsEdit"
		make new document
		activate
	end tell
end if

on appIsRunning(appName)
	tell application "System Events" to (name of processes) contains appName
end appIsRunning

I run all my scripts via the excellent script launcher FastScripts, but a QuickSilver trigger would work just as well. If the above script can save just one thought from evaporating into the ether before there’s a medium ready to capture it, I’ll consider it a success.

I say “almost” here since a single inconsistency of experience annoyingly presented itself after all of my tweaking: MarsEdit’s post preview window would automatically open whenever I began a new post. I am a big fan of the post preview feature of ME, which allows you to see exactly how your post will look on your blog even as you write it offline. For longer articles, though, I generally don’t like to open the preview window until I have the better part of the post written; for shorter, link-based quips I’d rather not bother with it at all. Therefore, having the preview window launch each time I opened the editor soon became a frustrating annoyance. How to turn it off?

I was just about to cry for help on the developer’s forums when I found what I was looking for: MarsEdit’s well-hidden Blog-specific Settings in the Weblog menu. Switch to the “Composing” tab and turn the Post Preview option to “Defaults to Closed.” I was smiling again.

Another gem in these settings is the ability for ME to alert you if you are about to send your post up to the net without filling in the tags section, choosing categories, writing an excerpt, etc (you define what’s important to you). This is a really useful feature that would have saved me many times in the past from hitting send only to quickly realize that I’d left the post “uncategorized.”

I’d consider myself a moderate to heavy MarsEdit user and it thus shocks me somewhat that these settings were so difficult for me to find. There’s enough in these blog sensitive settings that every MarsEdit user would benefit from their being more accessible.

Dropbox is becoming more popular and they have an excellent video tutorial up at their site that explains the fundamentals of the program, so I’m not going to waste words here describing how it works. Instead, I’ll talk about five things that I keep synced between my two Macs with the help of Dropbox. I hope it gives you some ideas.

My AppleScripts

As far as I’m concerned, any action that requires more than a total of two mouse clicks and will be done more than once is a good candidate for an AppleScript. Many of my scripts are no more than an few lines long. But even such a small amount of code, when run repeatedly via a keystroke over a long period, will rescue a significant portion of my life from the doldrums of repetitive drudgery. I use FastScripts to run my scripts.

My TextExpander Snippets

What AppleScript is for repetitive tasks, TextExpander is for repetitive typing. I recently wrote about how to use TextExpander to perform custom searches from Safari’s location bar and since then I’ve become completely addicted to the method. In the past I’ve used TextExpander primarily when developing new websites, but these custom URL searches have suddenly made TE more important to me than every before.

My 1Password Keychain

The web is a dangerous place I’m told. 1Password keeps you a little bit safer by allowing you to create crazy strong and unique logins for every site you visit and save them in its custom 1Password keychain. The only problem with this solution is that if you’re ever on a computer without 1Password, you’re pretty much out of luck for logging in anywhere. By keeping 1Password in sync across your Macs, you remove this obstacle. Unless, that is, you’re forced to use a PC at work, in which case you’re out of luck.

My TaskPaper To Dos

If you work on multiple Macs, having your To Dos synced across machines is a no brainer. As I’ve written, I use HogBay Software’s dead simple TaskPaper to keep track of my pending chores and sudden inspirations, and while I do very much like the uncluttered and themable UI, the main reason I love the application is the plain text format in which it stores your notes. Total portability and compatibility with any app that can read .txt. It’s pure convenience.

My MarsEdit Drafts Folder and Preferences

Though I use TextEdit for the majority of my writing needs, I turn to MarsEdit when it’s time to add some markup and images to my words before sending them up to the web. MarsEdit allows you to store local drafts of your posts and see exactly how they will look on your site even without an internet connection. Keeping all my drafts as well as my custom macros synced up between Macs really is a necessity for me.

Your Dropbox

This is of course my personal list of files and folders that I sync using Dropbox, and you likely have a very different set of apps which are critical to what you do on your computer. So in that case, are you a Dropbox user? Has it improved your life like it has mine? Doing something interesting with it? If so, let us know about it in the comments. And if not, hopefully this article has given you some ideas.

One useful feature common to most other writing apps is a word count calculator. Why Apple doesn’t include this simplest of features in their simplest writing app is a mystery to me (has anyone ever upgraded to Pages for word count alone?). But fortunately it’s easy enough to add word count to TextEdit via AppleScript and have it displayed by a Growl notification. Here’s how it looks and the script to make it happen:

The Script

tell application "GrowlHelperApp"
	tell application "TextEdit"
		activate
		set wrdCnt to count words of document 1
	end tell
	set defaultNotification to "TextEdit Word Count:"
	set myAllNotesList to {defaultNotification}
	register as application defaultNotification all notifications myAllNotesList ¬
		default notifications {defaultNotification} icon of application "TextEdit.app"
	notify with name defaultNotification title ¬
		defaultNotification description "Roughly " & wrdCnt ¬
		application name defaultNotification

end tell

There isn’t anything really special here, but it’s a useful little script to have in your toolbox. Let me know if you see anyway the script can be improved or made more useful.

Download Growl, a free and unintrusive event notification application for your Mac.

But as every would-be writer knows, getting started is half the battle. To ease the friction of entering into this ‘distraction free’ scenario, I made a little AppleScript to give you one less excuse.

tell application "Finder" to set windSz to bounds of window of desktop

set w1 to item 1 of windSz
set w2 to item 3 of windSz
set h1 to item 2 of windSz
set h2 to item 4 of windSz

set nw2 to (w2 * 0.7)
set nh2 to (h2 * 0.9)

set nw1 to (w2 - nw2)
set nh1 to ((h2 - nh2) - 20)

tell application "Backdrop" to activate

delay 0.1

tell application "TextEdit"
	activate
	set winNo to (count windows)
	if winNo is less than 1 then
		make new document
	end if
	set bounds of window 1 to {nw1, nh1, nw2, nh2}
end tell

What Does the Script Do?

Please have a look for yourself.

How Does the Script Work?

The above bit of AppleScript first checks your monitor size and does some calculations to determine an appropriate size for a TextEdit window. Secondly, it checks if you have a TextEdit document open. If so, it grabs it and resizes it in front of BackDrop. If not, it makes you a new one. It’s quite simple and, in my opinion doesn’t require much explanation. Let me know in the comments if you disagree.

Download BackDrop. It’s freeware.

Transforming the long and complicated URL from the App Store into an acceptable Twitter form, however, is a somewhat convoluted process. First open up a plain text TextEdit window and drag the app’s icon from iTunes onto the document. Next, open up bit.ly (or your favorite URL shortening service) in Safari, paste in the URL open in TextEdit to shorten it. Copy your new short link to the clipboard and you’re set to post to Twitter. (And then you can close the bit.ly page and quit TextEdit without saving…)

This process is prohibitively cumbersome. I cobbled together the following AppleScript to ease the pain of posting shortened App Store URLs to Twitter.

on open appURL
	tell application "Finder"
		set ClipURL to location of internet location file (appURL as text)
		ignoring case
			if ((characters 1 through 4 of ClipURL as string) is not "http") then
				return "Malformed URL."
			else
				set curlCMD to ¬
					"curl --stderr /dev/null \"http://bit.ly/api?url=" & ClipURL & "\""

				set bitlyURL to (do shell script curlCMD)

				set the clipboard to bitlyURL
				move appURL to the trash

				tell application "GrowlHelperApp"
					set defaultNotification to "URL Shortened"
					set myAllNotesList to {defaultNotification}
					register as application defaultNotification all notifications myAllNotesList ¬
						default notifications {defaultNotification} icon of application "Safari.app"
					notify with name defaultNotification title ¬
						defaultNotification description ¬
						"Your bit.ly URL is on the clipboard and ready to paste." application name defaultNotification

				end tell

			end if
		end ignoring
	end tell
end open

How to Use the Script

To set up the script, first copy the code into Script Editor and save it as an Application somewhere you’ll have easy access to it (the Desktop is a good place). Once your script is saved, using it is easy. Drag your link from iTunes out onto the desktop. Now drag it one more time onto the droplet. The URL will be shortened and put on the clipboard and the webloc from iTunes will be moved to the trash.

It’s really useful, although a little difficult to explain. This short video illustrates what the script does.

I created this script using two sources. AppleScript droplets cannot handle URLs dropped straight from Safari (or iTunes) so it’s necessary to drop them into the Finder first. To get the droplet to recognize the .webloc file I used the code posted here by an unknown forum member. To convert the URL using bit.ly, I used Jonathan Berger’s TextExpander script.

If you know a better way to get App Store URLs, let me know in the comments. For the moment, I’m quite happy with this method.

There are a lot of Twitter apps for the Mac. I’ve tried most of them, but I keep coming back to Twitterrific. Its simple interface does what I want, when I want. Some of the competitors offer interesting features, but none of them work well enough to tear me away from Twitterrific. I do have a wish-list for Twitterrific that’s about a mile long—but again, that’s another story. Despite my recognition of its flaws, Twitterrific’s the Twitter app that works the best for me.

I couldn’t agree more with this sentiment. While we wait for a power user release of Twitterrific, here are a few of my own tricks and scripts that make the little app more usable for me.

See Realtime Responses to Any Tweeter

Twitter is an excellent way to get questions answered by others who may have first hand experience with your query. Sometimes, however, it isn’t you who asks the question, but someone you follow. If you want to see how people are replying to everyone in your timeline you can enable this in Twitter’s preferences. To do so, go to the Notifications tab under your account settings and select Show Me ‘all @ replies’ from the drop down menu. With this preference enabled, every time one of your followees is replied to, you’ll see the reply in Twitterrific.

Personally I don’t want to see everyone’s responses – it crowds Twitterrific. But there are still times when I do want to see responses to some particular Tweeter. When that happens, I use this simple script.

tell application "Twitterrific" to set theTweeter ¬
	to the screen name of selection
try
	tell application "System Events"
		key code 53
	end tell
end try
tell application "Safari" to open location ¬
	"http://search.twitter.com/search?q=" & ¬
	"@" & theTweeter

To use the script, have the tweet selected in Twitterrific that you want to see replies to. When the script is run it will open a Safari page with all the responses to the selected Twitter user. Until Twitter provides a way to see responses to a particular tweet and not just a user, it’s the best solution I can think of.

Open Links in a Tweet Via the Keyboard

Twitterrific has fair keyboard support, but one action that always had me reaching of the mouse was opening links embedded in Tweets. This script will look for links in Tweets and open them in Safari.

tell application "Twitterrific" to set theTweet to text of selection
try
	tell application "System Events"
		key code 53
	end tell
end try

-- John Maisey -- 29 Jan 2009 -- www.nhoj.co.uk --

set myResult to {}
-- Items that you expect will be after the end of the URL.
set terminatorList to {" ", ">", ".", ",", ")", return, tab}
-- Split by 'http://" and only get the second to the last parts.
set myList to my textItemDelimiterSplit(theTweet, "http://", 2, -1)
-- Loop through list returned.
repeat with myItem in myList
	-- Loop through possible ending characters .
	repeat with myTerminator in terminatorList
		-- Split by the ending character.
		set myItem to my textItemDelimiterSplit(myItem, myTerminator, 1, 1)
	end repeat
	-- Add the result to an array.
	set myResult to myResult & ("http://" & myItem as text)
end repeat
try
	open location myResult
end try
on textItemDelimiterSplit(theText, theTID, theFrom, theTo)
	try
		set my text item delimiters to theTID
		set myReturn to text items theFrom thru theTo of theText
		set my text item delimiters to {""}
		return myReturn
	on error
		return {}
	end try
end textItemDelimiterSplit

An important note: The meat of this script was written by the very talented John Maisley, the maker of iCal Dupe Deleter. A big thanks to John for his help here. I have left his relevant in-script annotations intact.

Translate a Tweet

As I’ve mentioned before, I’m currently living in Korea and making some attempt to learn a bit of the language. To this end, I follow a few Korean speaking Twitter users. My Korean is coming along, but much of the time I still need some help from Google Translate. The following script will translate (almost) any selected Tweet in Twitterrific into English using Google Translate.

tell application "Twitterrific" to set transMe to text of selection
try
	tell application "System Events"
		key code 53
	end tell
end try
tell application "Safari" to open location ¬
	"http://translate.google.com/translate_t?text=" & ¬
	transMe & "&hl=en&langpair=auto|en&tbb=1&ie=UTF-8#"

Get the Permalink for a Tweet

Occasionally I want the permalink for an interesting Tweet and there are two quick ways to get this in Twitterrific. Firstly, you can simply click and drag the Tweeter’s user picture associated with the Tweet onto Safari’s icon. Safari will open up the permalink in a new tab. If you don’t want to bother with the mouse, however, you can use this simple AppleScript:

tell application "Twitterrific"
	set theId to the id of selection
	set scrnName to the screen name of selection
end tell
try
	tell application "System Events"
		key code 53
	end tell
end try
tell application "Safari" to open location ¬
	"http://twitter.com/" & scrnName & ¬
	"/statuses/" & theId

Make Growl Notifications of Replies to Your Tweets Sticky

Twitterrific has built in Growl support which throws up a notification whenever new tweets are retrieved in Twitterrific. If you can handle the distraction, this is the best way to keep real-time tabs on everything that’s happening in the Twitter lives of those you follow. Despite the ‘in your face’ nature of Growl notifications, however, there is also a decided transience to their usefulness. One can become quiet immune to their presence when they’re always popping up. When someone replies to me on Twitter, I want to know it. Thankfully, it’s easy to enable ’sticky’ Growl notifications for Tweets which contain replies to you.

Open up Growl’s preference pane and navigate to the Applications tab. Find Twitterrific in the list of supported apps and double click it. Under the Notifications tab, select ‘Reply Arrived’ and set Stay on Screen to ‘Always.’ You can even add a sound to the notification if you like. With Growl set up this way, each time someone replies to you in Twitter that Tweet’s Growl notification will stick around until you intentionally dismiss it.

My favorite way to run AppleScripts is FastScripts, which allows you to add keyboard shortcuts to scripts and limit their scope to application sensitive contexts. If you have any trouble with any of the scripts here let me know and I’ll see what I can do.

You can follow @PeterVk on Twitter (that’s me) or @MacMembrane to receive links to all the latest posts. If you have any of your own Twitterrific or Twitter tips post them in the comments for everyone to see. Happy Tweeting.

Use CompFight to Search Flickr

CompFight does away with Flickr’s stingy 10 search results page and replaces it with browser wide thumbnail results based on your keywords. It also let’s you add Creative Commons/Commercial paramarers to your search. I leave these on so that my results are narrowed to only images that I can use on my blog without violating copyright.

Search CompFight from MarsEdit using AppleScript

As I said, I use CompFight to search images for my blog, and when I’m writing for my blog I’m in MarsEdit. Here is an AppleScript to take the selected text from a MarsEdit and search CompFight for CC images.

tell application "MarsEdit"
	activate
	try
		set needImg to selected text in document 1
	end try
end tell

try
	if needImg is equal to "" then
		activate me
		try
			set needImg to text returned of ¬
				(display dialog "Enter keywords to search CompFight:" with title ¬
					"Nothing Selected" default answer "" buttons ¬
					{"No Thanks", "Search"} default button 2)
		end try

		my addSyntax(needImg)

	else

		my addSyntax(needImg)

	end if
end try

on addSyntax(needImg)
	if needImg is not "" then
		set AppleScript's text item delimiters to " "
		set theTextItems to text items of needImg
		set AppleScript's text item delimiters to "%20"
		set needImg to theTextItems as string
		set AppleScript's text item delimiters to {""}
		open location "http://www.compfight.com/#search_type=tags&query=" & ¬
			needImg & ¬
			"&commit=Search&license=1%2C2%2C3%2C4%2C5%2C6&original=1&safe_search=3"
	end if
end addSyntax

How to Use the Script

Copy and paste the above code into Script Editor (in Applications >> AppleScript) and save it to your scripts folder. Select some text in MarsEdit and run the script. A new browser window will open with your search terms pre-populated. Because the script adds the CC parameters to your search, any image you see should be usable on your blog.

It isn’t the most complicated script in the world, but it does eliminate a few steps when searching for blog images, and eliminating simple but repetitive tasks is what AppleScript is all about.

Need some more MarsEdit AppleScripts and tricks? Try 2 AppleScripts to Simplify Your MarsEdit Workflow and MarsEdit Breaks it’s Silence with Sent to Weblog Sound. And don’t forget to Subscribe to MacMembrane.

A quick solution I’ve found to greatly reduce this occurrence is to set the background color of Preview to that of my blog. This way, if some unremoved piece of background doesn’t appear against the grey background of Preview but will when seen against the background of MacMembrane, I’ll know it and save myself some hassle. Setting it up is easy.

First open up your blog in Safari. Open Preview and open its preferences by hitting Cmd + , (comma) or select Preferences from the application menu. Under the General tab click on the Window Background sample and OS X’s ubiquitous color picker will pop up. Click on the magnifying glass and then on the background of your blog in Safari. Now Preview will give you an accurate representation of alpha images as they will appear once posted.

Preview is one of those smallish apps included with OS X that packs much more power than it initially lets on. For simple tasks, the speed of Preview can’t be beat. I hope this small tweak helps you out.

Despite being somewhat embarrassed by this response (‘Why didn’t I think of that myself?’), I was really happy with the suggestion because it meant the solution to my desire was very easily achieved. Here’s how to use Growl to make MarsEdit play a ‘Successfully Posted’ sound. But first…

What are these applications?

MarsEdit is a plain text blogging client for the Mac that has a wealth of features that should satisfy the needs of most bloggers. I’ve written extensively about MarsEdit in the past so I won’t say too much about the application here other than to note that I’m a huge fan. If you want to see if MarsEdit is right for you then head over to Red Sweater Software to download a free 30 day trial. It’s 29.95 thereafter.

Growl is a kind of all-purpose visual and audio notification utility for your Mac. Growl is supported by a slew of applications natively (I use ’slew’ because I can’t find a precise number on the web!) and many more by adding simple plugins. In short, Growl lets you know what’s happening with an application when it’s not in the front, everything from displaying incoming mail to alerting you to new tweets in Twitterific. Growl is freeware.

Make them work together.

Like many apps, MarsEdit supports Growl notifications out of the box, letting you know if your new post has made it to your blog or been tripped up along the way. Because of this native support, it’s easy to add a sound to accompany the visual notification.

Open System Preferences and find the Growl preference pane at the bottom of the panel. Click on the Applications tab at the top of Growl’s preferences. Scroll down to find MarsEdit and double click the icon to edit the app’s alert preferences. Click on the Notifications tab. (Click the screenshot to enlarge.)

MarsEdit supports Growl notifications for four of it’s common tasks: Finished Refreshing Weblog, Finished Uploading File and, the task that concerns us here, Finished Sending to Weblog. Select the latter from the drop down notification list and set the Play Sound drop down menu to whatever you’d like to hear when MarsEdit sends up your writing to the web. Now MarsEdit will make some noise when it posts to your blog. Satisfying!

I’m quite pleased with this solution, although I do hope that MarsEdit adds a custom sound to its repertoire of features someday. Thanks to the developer for his ultra-fast, non-condesending reply on Twitter as well!

You can follow both MarsEdit and myself on Twitter. If you want to find some more great blogging tools, try Tools to Turn Your Mac into a Blogger’s Dream. If you already use MarsEdit, you might like these Two AppleScripts to Simplify Your MarsEdit Workflow.